Conectați-vă cu Microsoft
Conectați-vă sau creați un cont
Salut,
Selectați un alt cont.
Aveți mai multe conturi
Alegeți contul cu care doriți să vă conectați.

Sfat: Încercați să utilizați noua funcție XLOOKUP , o versiune îmbunătățită de VLOOKUP care funcționează în orice direcție și returnează potriviri exacte în mod implicit, făcând utilizarea mai simplă și mai convenabilă decât predecesorul său.

Utilizați VLOOKUP atunci când trebuie să găsiți lucruri într-un tabel sau într-o zonă după rând. De exemplu, căutați prețul unei piese auto după numărul piesei sau găsiți un nume de angajat pe baza ID-ului său de angajat.

În forma sa cea mai simplă, funcția VLOOKUP spune:

=VLOOKUP(Ce doriți să căutați, unde doriți să căutați, numărul coloanei din zona care conține valoarea de returnat, returnează o potrivire aproximativă sau exactă - indicată ca 1/TRUE sau 0/FALSE).

Browserul nu acceptă redarea video. Instalați Microsoft Silverlight, Adobe Flash Player sau Internet Explorer 9.

Sfat: Secretul pentru VLOOKUP este să vă organizați datele astfel încât valoarea pe care o căutați (Fruct) să se afle în partea stângă a valorii returnate (Cantitatea) pe care doriți să o găsiți.

Utilizați funcția VLOOKUP pentru a căuta o valoare într-un tabel.

Sintaxă 

VLOOKUP(valoare_căutare, matrice_tabel, num_index_col, [căutare_zonă])

De exemplu:

  • =VLOOKUP(A2;A10:C20;2;TRUE)

  • =VLOOKUP("Munteanu",B2:E7,2,FALSE)

  • =VLOOKUP(A2,'Detalii client'! A:F,3,FALSE)

Nume argument

Descriere

valoare_căutare    (obligatoriu)

Valoarea pe care doriți să o căutați. Valoarea pe care doriți să o căutați trebuie să fie în prima coloană a zonei de celule pe care o specificați în argumentul table_array .

De exemplu, dacă matrice-tabel se întinde pe celulele B2:D7, atunci lookup_value trebuie să fie în coloana B.

Valoare_căutare poate fi o valoare sau o referință la o celulă.

matrice_tabel    (obligatorie)

Zona de celule în care va căuta VLOOKUP o valoare_căutare și valoarea returnată. Puteți utiliza o zonă denumită sau un tabel și puteți utiliza nume în argument în locul referințelor la celule. 

Prima coloană din zona de celule trebuie să conțină lookup_value. Zona de celule trebuie, de asemenea, să includă valoarea returnată pe care doriți să o găsiți.

Aflați cum să selectați zone într-o foaie de lucru.

num_index_col    (obligatoriu)

Numărul coloanei (începând cu 1 pentru coloana din partea stângă a table_array) care conține valoarea returnată.

zonă_căutare   (opțional)

O valoare logică, care specifică dacă doriți ca VLOOKUP să caute o potrivire exactă sau o potrivire aproximativă:

  • Potrivire aproximativă - 1/TRUE presupune că prima coloană din tabel este sortată numeric sau alfabetic, apoi va căuta cea mai apropiată valoare. Aceasta este metoda implicită dacă nu specificați alta. De exemplu, =VLOOKUP(90,A1:B100,2,TRUE).

  • Potrivire exactă - 0/FALSE caută valoarea exactă din prima coloană. De exemplu, =VLOOKUP("Smith",A1:B100,2,FALSE).

Cum începeți

Există patru informații de care aveți nevoie pentru a construi sintaxa VLOOKUP:

  1. Valoarea pe care doriți să o căutați, numită și valoare de căutare.

  2. Zona în care se află valoarea de căutare. Rețineți că valoarea de căutare trebuie să fie întotdeauna în prima coloană din zonă pentru ca VLOOKUP să funcționeze corect. De exemplu, dacă valoarea de căutare se află în celula C2, zona trebuie să înceapă cu C.

  3. Numărul coloanei din zona care conține valoarea returnată. De exemplu, dacă specificați B2:D11 ca zonă, ar trebui să contorizați B ca prima coloană, C a doua și așa mai departe.

  4. Opțional, puteți specifica TRUE dacă doriți o potrivire aproximativă sau FALSE dacă doriți o potrivire exactă a valorii returnate. Dacă nu faceți nicio specificare, valoarea implicită va fi întotdeauna TRUE sau potrivire aproximativă.

Acum alăturați toate elementele de mai sus, după cum urmează:

=VLOOKUP(valoare de căutare, zonă care conține valoarea de căutare, numărul coloanei din zona care conține valoarea returnată, Potrivire aproximativă (TRUE) sau Potrivire exactă (FALSE)).

Exemple

Iată câteva exemple de VLOOKUP:

Exemplul 1

=VLOOKUP (B3,B2:E7,2,FALSE)

VLOOKUP caută Fontana în prima coloană (coloana B) din table_array B2:E7 și returnează Olivier din a doua coloană (coloana C) a table_array.  False returnează o potrivire exactă.

Exemplul 2

=VLOOKUP (102,A2:C7,2,FALSE)

VLOOKUP caută o potrivire exactă (FALSE) a numelui de familie pentru 102 (lookup_value) în a doua coloană (coloana B) din zona A2:C7 și returnează Fontana.

Exemplul 3

=IF(VLOOKUP(103;A1:E7;2;FALSE)="Souse","Located","Not found")

IF verifică dacă VLOOKUP returnează Sousa ca nume de familie al angajatului, corelat cu 103 (lookup_value) în A1:E7 (table_array). Deoarece numele de familie corespunzător lui 103 este Leal, se afișează condiția IF este falsă și Negăsit.

Exemplul 4

=INT(YEARFRAC(DATE(2014;6;30),VLOOKUP(105;A2:E7;5;FLASE);1))

VLOOKUP caută data nașterii angajatului corespunzătoare cu 109 (lookup_value) în intervalul A2:E7 (table_array) și returnează 04.03.1955. Apoi, YEARFRAC scade această dată de naștere din 2014/6/30 și returnează o valoare, care este apoi convertită de INY la întregul 59.

Exemplul 5

IF(ISNA(VLOOKUP(105,A2:E7,2,FLASE))=TRUE,"Angajat negăsit",VLOOKUP(105,A2:E7,2,FALSE))

IF verifică dacă VLOOKUP returnează o valoare pentru numele de familie din coloana B pentru 105 (lookup_value). Dacă VLOOKUP găsește un nume de familie, atunci IF va afișa numele de familie, altfel, IF returnează Angajatul nu a fost găsit. ISNA se asigură că, dacă VLOOKUP returnează #N/A, atunci eroarea este înlocuită cu Angajatul nu a fost găsit, în loc de #N/A.



În acest exemplu, valoarea returnată este Burke, care este numele de familie corespunzător lui 105.

Puteți utiliza VLOOKUP pentru a combina mai multe tabele într-unul singur, atât timp cât unul dintre tabele are câmpuri în comun cu toate celelalte. Acest lucru poate fi util mai ales dacă trebuie să partajați un registru de lucru cu persoane care au versiuni mai vechi de Excel care nu acceptă caracteristici de date cu mai multe tabele ca surse de date - combinând sursele într-un singur tabel și modificând sursa de date a caracteristicii de date la noul tabel, caracteristica de date poate fi utilizată în versiunile mai vechi de Excel (cu condiția ca caracteristica de date în sine să fie acceptată de versiunea mai veche).

O foaie de lucru cu coloane care utilizează VLOOKUP pentru a obține date din alte tabele

Aici, coloanele A-F și H au valori sau formule care utilizează doar valori în foaia de lucru, iar restul coloanelor utilizează VLOOKUP și valorile din coloana A (Cod client) și coloana B (Avocat) pentru a obține date din alte tabele.

  1. Copiați tabelul care conține câmpurile comune într-o foaie de lucru nouă și dați-i un nume.

  2. Faceți clic pe Instrumente de date > >Relații pentru a deschide caseta de dialog Gestionare relații.

    Caseta de dialog Gestionare relații
  3. Pentru fiecare relație listată, rețineți următoarele:

    • Câmpul care leagă tabelele (listat între paranteze în caseta de dialog). Aceasta este lookup_value pentru formula VLOOKUP.

    • Numele tabelului de căutare asociat. Aceasta este table_array din formula VLOOKUP.

    • Câmpul (coloana) din tabelul de căutare asociat care conține datele pe care le doriți în noua coloană. Aceste informații nu sunt afișate în caseta de dialog Gestionare relații - va trebui să consultați Tabelul de căutare asociat pentru a vedea ce câmp doriți să regăsiți. Notați numărul coloanei (A=1) - acesta este col_index_num din formulă.

  4. Pentru a adăuga un câmp la noul tabel, introduceți formula VLOOKUP în prima coloană necompletată utilizând informațiile colectate la pasul 3.

    În exemplul nostru, coloana G utilizează Attorney ( lookup_value) pentru a obține datele Bill Rate din a patra coloană (col_index_num = 4) din tabelul foii de lucru Avocați, tblAttorneys ( table_array), cu formula =VLOOKUP([@Attorney],tbl_Attorneys,4,FALSE).

    Formula poate utiliza, de asemenea, o referință de celulă și o referință de zonă. În exemplul nostru, ar fi =VLOOKUP(A2,'Attorneys'! A:D,4,FALSE).

  5. Continuați să adăugați câmpuri până când aveți toate câmpurile de care aveți nevoie. Dacă încercați să pregătiți un registru de lucru care conține caracteristici de date care utilizează mai multe tabele, modificați sursa de date a caracteristicii de date la noul tabel.

Problemă

Ce nu a funcționat

Valoarea greșită returnată

În cazul în care zonă_căutare este TRUE sau omisă, prima coloană trebuie sortată în ordine alfabetică sau numerică. Dacă prima coloană nu este sortată, valoarea returnată poate fi una la care nu vă așteptați. Sortați prima coloană sau utilizați FALSE pentru o potrivire exactă.

#N/A în celulă

  • În cazul în care parametrul zonă_căutare este TRUE, dacă valoarea din valoare_căutare este mai mică decât cea mai mică valoare din prima coloană din matrice_tabel, veți obține valoarea de eroare #N/A.

  • În cazul în care zonă_căutare este FALSE, valoarea de eroare #N/A indică faptul că numărul exact nu este găsit.

Pentru mai multe informații despre rezolvarea erorilor #N/A în VLOOKUP, consultați Cum să remediați o eroare #N/A în funcția VLOOKUP.

#REF! în celulă

Dacă col_index_num este mai mare decât numărul de coloane din matrice-tabel, veți primi #REF! .

Pentru mai multe informații despre rezolvarea #REF! din VLOOKUP, consultați Cum să remediați o eroare #REF!.

#VALUE! în celulă

Dacă table_array este mai mic decât 1, veți primi #VALUE! .

Pentru mai multe informații despre rezolvarea erorilor #VALUE! în VLOOKUP, consultați Cum să remediați o eroare #VALUE! în funcția VLOOKUP.

#NAME? în celulă

Valoarea de eroare #NAME? înseamnă, de obicei, că lipsesc ghilimelele din formulă. Pentru a căuta numele unei persoane, aveți grijă ca în formulă să încadrați numele între ghilimele. De exemplu, introduceți numele ca "Munteanu" în = VLOOKUP("Munteanu",B2:E7,2,FALSE).

Pentru mai multe informații, consultați Corectarea unei erori #NAME!.

#SPILL! în celulă

Această eroare particulară #SPILL! înseamnă de obicei că formula se bazează pe intersecție implicită pentru valoarea de căutare și utilizează o coloană întreagă ca referință. De exemplu, =VLOOKUP(A:A,A:C,2,FALSE). Puteți rezolva problema prin ancorarea referinței de căutare cu operatorul @ astfel: =VLOOKUP(@A:A,A:C,2,FALSE). Alternativ, puteți să utilizați metoda VLOOKUP tradițională și să faceți referire la o singură celulă în locul unei coloane întregi: =VLOOKUP(A2,A:C,2,FALSE).

Faceți așa

De ce?

Utilizați referințe absolute pentru zonă_căutare

Utilizarea de referințe absolute vă permite să completați în jos o formulă, astfel încât să caute întotdeauna în exact aceeași zonă de căutare.

Aflați cum să utilizați referințe absolute la celule.

Nu stocați valori număr sau dată calendaristică sub formă de text.

Atunci când se caută valori numerice sau date, asigurați-vă că datele din prima coloană din matrice_tabel nu sunt stocate ca valori text. Altfel, VLOOKUP poate returna o valoare incorectă sau neașteptată.

Sortați prima coloană

Sortați prima coloană din matrice_tabel înainte să utilizați VLOOKUP atunci când zonă_căutare este TRUE.

Utilizați caractere wildcard

Dacă zonă_căutare este FALSE și valoare_căutare este text, puteți utiliza caracterele wildcard - semnul de întrebare (?) și asteriscul (*) - în valoare_căutare. Un semn de întrebare se potrivește cu orice caracter individual. Asteriscul se potrivește cu orice secvență de caractere. Dacă doriți să găsiți un semn de întrebare sau un asterisc, tastați tilda (~) în fața caracterului.

De exemplu, =VLOOKUP("Fontan?",B2:E7,2,FALSE) va căuta toate instanțele Din Fontana cu o ultimă literă care poate varia.

Asigurați-vă că datele dvs. nu conțin caractere greșite.

Când se caută valori text în prima coloană, asigurați-vă că datele din prima coloană nu conțin spații la început, spații la sfârșit, utilizări neuniforme ale apostrofului sau ghilimelelor drepte ( ' sau " ), ori ghilimele curbate ( ‘ sau “ ) sau caractere neimprimabile. În aceste cazuri, VLOOKUP poate returna o valoare neașteptată.

Pentru a obține rezultate corecte, încercați să utilizați funcția CLEAN sau funcția TRIM pentru a elimina spațiile aflate după valorile din celulele tabelului.

Aveți nevoie de ajutor suplimentar?

Puteți oricând să întrebați un expert din Comunitatea tehnică Excel sau să obțineți asistență în Comunități.

Consultați și

Funcția XLOOKUP

Video: Când și cum se utilizează VLOOKUP

Cartelă de referințe rapide: instrumentul de reîmprospătare VLOOKUP

Cum să remediați o eroare #N/A în funcția VLOOKUP

Căutarea valorilor cu VLOOKUP, INDEX sau MATCH

Funcția HLOOKUP

Aveți nevoie de ajutor suplimentar?

Doriți mai multe opțiuni?

Explorați avantajele abonamentului, navigați prin cursurile de instruire, aflați cum să vă securizați dispozitivul și multe altele.

Comunitățile vă ajută să adresați întrebări și să răspundeți la întrebări, să oferiți feedback și să primiți feedback de la experți cu cunoștințe bogate.

Au fost utile aceste informații?

Cât de mulțumit sunteți de calitatea limbajului?
Ce v-a afectat experiența?
Apăsând pe Trimitere, feedbackul dvs. va fi utilizat pentru a îmbunătăți produsele și serviciile Microsoft. Administratorul dvs. IT va avea posibilitatea să colecteze aceste date. Angajamentul de respectare a confidențialității.

Vă mulțumim pentru feedback!

×