Przejdź do głównej zawartości
Pomoc techniczna
Zaloguj się przy użyciu konta Microsoft
Zaloguj się lub utwórz konto.
Witaj,
Wybierz inne konto.
Masz wiele kont
Wybierz konto, za pomocą którego chcesz się zalogować.

Porada: Spróbuj użyć nowej funkcji X.WYSZUKAJ – ulepszonej wersji funkcji VLOOKUP, która działa w dowolnym kierunku i domyślnie zwraca dokładne dopasowania, dzięki czemu korzystanie z nich jest łatwiejsze i wygodniejsze niż w poprzedniej wersji.

Funkcja WYSZUKAJ.PIONOWO umożliwia znajdowanie elementów w tabeli lub zakresie według wierszy. Na przykład wyszukaj cenę części samochodowej według numeru części lub znajdź nazwisko pracownika na podstawie jego identyfikatora pracownika.

Mówiąc najprościej, działanie funkcji WYSZUKAJ.PIONOWO jest następujące:

=WYSZUKAJ.PIONOWO(Co chcesz wyszukać, gdzie chcesz to wyszukać, numer kolumny w zakresie zawierającym wartość do zwrócenia, zwróć przybliżone lub dokładne dopasowanie – wskazane jako 1/PRAWDA lub 0/FAŁSZ).

Twoja przeglądarka nie obsługuje wideo. Zainstaluj dodatek Microsoft Silverlight, Adobe Flash Player lub program Internet Explorer 9.

Porada: Pomyślność działania funkcji WYSZUKAJ.PIONOWO zależy od prawidłowego uporządkowania danych: szukana wartość (Owoc) musi znajdować się po lewej stronie zwracanej wartości, którą chcesz znaleźć (Kwota).

Użyj funkcji WYSZUKAJ.PIONOWO do wyszukiwania wartości w tabeli.

Składnia 

WYSZUKAJ.PIONOWO(szukana_wartość; tabela_tablica; nr_kolumny; [przeszukiwany_zakres])

Na przykład:

  • =WYSZUKAJ.PIONOWO(A2,A10:C20,2,PRAWDA)

  • =WYSZUKAJ.PIONOWO("Pawłowski";B2:E7;2;FAŁSZ)

  • =WYSZUKAJ.PIONOWO(A2,'Szczegóły klienta'! A:F,3,FAŁSZ)

Nazwa argumentu

Opis

szukana_wartość    (wymagany)

Wartość, która ma zostać znaleziona. Wartość, która ma zostać znaleziona, musi być w pierwszej kolumnie zakresu komórek określonego za pomocą argumentu tabela_tablica.

Jeśli na przykład wartość argumentu tabela_tablica obejmuje komórki B2:D7, szukana_wartość musi znajdować się w kolumnie B.

Szukana_wartość może być wartością lub odwołaniem do komórki.

tabela_tablica    (wymagany)

Zakres komórek, w których funkcja WYSZUKAJ.PIONOWO szuka wartości szukana_wartość i wartości zwracanej. Możesz użyć nazwanego zakresu lub tabeli i użyć nazw w argumencie zamiast odwołań do komórek. 

Pierwsza kolumna w zakresie komórek musi zawierać szukana_wartość. Zakres komórek musi również zawierać zwracaną wartość, którą chcesz znaleźć.

Dowiedz się, jak zaznaczać zakresy w arkuszu.

nr_kolumny    (wymagany)

Numer kolumny (począwszy od 1 dla pierwszej z lewej kolumny w ramach zakresu tabela_tablica) zawierającej wartość zwracaną.

przeszukiwany_zakres    (opcjonalny)

Wartość logiczna określająca, czy funkcja WYSZUKAJ.PIONOWO ma znaleźć dopasowanie przybliżone, czy dokładne:

  • Przybliżone dopasowanie - 1/PRAWDA — powoduje wyszukanie najbliższej wartości przy założeniu, że pierwsza kolumna w tabeli jest posortowana liczbowo lub alfabetycznie. Jeśli nie określisz metody, ta metoda jest stosowana domyślnie. Na przykład =WYSZUKAJ.PIONOWO(90,A1:B100,2,PRAWDA).

  • Dokładne dopasowanie - 0/FAŁSZ — powoduje wyszukanie dokładnej wartości w pierwszej kolumnie. Na przykład, =WYSZUKAJ.PIONOWO("Kowalski",A1:B100,2,FAŁSZ).

Jak zacząć

Istnieją cztery informacje, które są potrzebne w celu utworzenia składni funkcji WYSZUKAJ.PIONOWO:

  1. Wartość, którą chcesz znaleźć, nazywana również szukaną wartością.

  2. Zakres, w którym znajduje się szukana wartość. Pamiętaj, że szukana wartość powinna zawsze znajdować się w pierwszej kolumnie zakresu dla funkcji WYSZUKAJ.PIONOWO, aby działała ona prawidłowo. Jeśli na przykład szukana wartość znajduje się w komórce C2, to zakres powinien rozpoczynać się od kolumny C.

  3. Numer kolumny w zakresie, który zawiera wartość zwracaną. Jeśli na przykład określisz zakres B2:D11, należy liczyć kolumnę B jako pierwszą kolumnę, C jako drugą i tak dalej.

  4. Opcjonalnie możesz określić wartość PRAWDA, jeśli potrzebujesz dopasowania przybliżonego, lub FAŁSZ, jeśli potrzebujesz dopasowania dokładnego wartości zwracanej. Jeśli nic nie określisz, wartością domyślną będzie zawsze PRAWDA, czyli dopasowanie przybliżone.

Teraz złóż wszystkie powyższe składniki w całość w następujący sposób:

=WYSZUKAJ.PIONOWO(szukana wartość, zakres zawierający szukaną wartość, numer kolumny w zakresie zawierającym zwracaną wartość, Przybliżone dopasowanie (PRAWDA) lub Dokładne dopasowanie (FAŁSZ)).

Przykłady

Oto kilka przykładów funkcji WYSZUKAJ.PIONOWO:

Przykład 1

=WYSZUKAJ.PIONOWO (B3,B2:E7,2,FAŁSZ)

Funkcja WYSZUKAJ.PIONOWO wyszukuje wartość Pawłowski w pierwszej kolumnie (B) tabeli tabela_tablica B3:E7 i zwraca wartość Marcin znalezioną w drugiej kolumnie (C) tabeli tabela_tablica.  Fałsz zwraca dokładne dopasowanie.

Przykład 2

=WYSZUKAJ.PIONOWO (102,A2:C7,2,FAŁSZ)

Funkcja WYSZUKAJ.PIONOWO szuka dokładnego dopasowania (FAŁSZ) nazwiska dla 102 (szukana_wartość) w drugiej kolumnie (kolumna B) w zakresie A2:C7 i zwraca wartość Pawłowski.

Przykład 3

=JEŻELI(WYSZUKAJ.PIONOWO(103,A1:E7,2,FAŁSZ)=" Michalski"," Znaleziono"," Nie znaleziono")

JEŻELI sprawdza, czy WYSZUKAJ.PIONOWO zwraca Michalski jako nazwisko pracownika odpowiadające 103 (szukana_wartość) w A1:E7 (tabela_tablica). Ponieważ nazwisko odpowiadające wartości 103 to Zawadzki, warunek JEŻELI ma wartość fałsz, a wartość Nie znaleziono jest wyświetlana.

Przykład 4

=INT(CZĘŚĆ.ROKU(DATA(2014,6,30),WYSZUKAJ.PIONOWO(105,A2:E7,5,FAŁSZ),1))



Funkcja WYSZUKAJ.PIONOWO wyszukuje datę urodzenia pracownika odpowiadającą wartości 109 (szukana_wartość) w zakresie A2:E7 (tabela_tablica) i zwraca datę 04.03.1955. Następnie funkcja CZĘŚĆ.ROKU odejmuje tę datę urodzenia od 30.06.2014 i zwraca wartość, która jest następnie konwertowana przez INY na liczbę całkowitą 59.

Przykład 5

JEŻELI(CZY.BRAK(WYSZUKAJ.PIONOWO(105,A2:E7,2,FAŁSZ))=PRAWDA,"Nie znaleziono pracownika",WYSZUKAJ.PIONOWO(105,A2:E7,2,FAŁSZ))



JEŻELI sprawdza, czy funkcja WYSZUKAJ.PIONOWO zwraca wartość nazwiska z kolumny B dla 105 (szukana_watość). Jeśli funkcja WYSZUKAJ.PIONOWO znajdzie nazwisko, funkcja JEŻELI wyświetli nazwisko. W przeciwnym razie funkcja JEŻELI zwróci wartość Nie znaleziono pracownika. CZY.BRAK upewnia się, że jeśli funkcja WYSZUKAJ.PIONOWO zwraca #Brak, błąd zostanie zastąpiony wartością Nie znaleziono pracownika, a nie #Brak.



W tym przykładzie zwracaną wartością jest Ostrowski, czyli nazwisko odpowiadające 105.

Funkcja WYSZUKAJ.PIONOWO umożliwia łączenie wielu tabel w jedną, o ile jedna z tabel ma wspólne pola ze wszystkimi innymi tabelami. Może to być szczególnie przydatne, jeśli musisz udostępnić skoroszyt osobom, które mają starsze wersje programu Excel, które nie obsługują funkcji danych z wieloma tabelami jako źródłami danych — łącząc źródła w jedną tabelę i zmieniając źródło danych funkcji danych na nową tabelę, funkcja danych może być używana w starszych wersjach programu Excel (pod warunkiem, że sama funkcja danych jest obsługiwana przez starszą wersję).

Arkusz z kolumnami, które używają funkcji WYSZUKAJ.PIONOWO do pobierania danych z innych tabel

W tym przypadku kolumny A-F i H zawierają wartości lub formuły, które używają tylko wartości w arkuszu, a pozostałe kolumny używają funkcji WYSZUKAJ.PIONOWO, a wartości kolumny A (kod klienta) i kolumny B (prawnik) do pobierania danych z innych tabel.

  1. Skopiuj tabelę zawierającą typowe pola do nowego arkusza i nadaj jej nazwę.

  2. Kliknij Dane > Narzędzia danych > Relacje, aby otworzyć okno dialogowe Zarządzanie relacjami.

    Zamknij okno dialogowe Zarządzanie relacjami.
  3. Dla każdej wymienionej relacji należy zwrócić uwagę na następujące kwestie:

    • Pole łączące tabele (wyświetlane w nawiasach w oknie dialogowym). Jest to szukana_wartość dla formuły WYSZUKAJ.PIONOWO.

    • Nazwa Pokrewnej tabeli odnośników. Jest to tabela_tablica w formule WYSZUKAJ.PIONOWO.

    • Pole (kolumna) w Pokrewnej tabeli odnośników, zawierające dane, które chcesz umieścić w nowej kolumnie. Te informacje nie są wyświetlane w oknie dialogowym Zarządzanie relacjami — musisz przejrzeć Pokrewną tabelę odnośników, aby zobaczyć, które pole chcesz pobrać. Musisz zanotować numer kolumny (A=1) — jest to nr_kolumny w formule.

  4. Aby dodać pole do nowej tabeli, wprowadź formułę WYSZUKAJ.PIONOWO w pierwszej pustej kolumnie, korzystając z informacji zebranych w kroku 3.

    W naszym przykładzie kolumna G używa kolumny Prawnik (szukana_wartość), aby uzyskać dane z czwartej kolumny Stawka (nr_kolumny = 4) z tabeli arkusza Prawnicy, tbl_Prawnicy (tabela_tablica), z formułą =WYSZUKAJ.PIONOWO([@Prawnik],tbl_Prawnicy,4,FAŁSZ).

    Formuła może również używać odwołania do komórki i zakresu. W naszym przykładzie jest to =WYSZUKAJ.PIONOWO(A2;'Prawnicy'!A:D,4,FAŁSZ).

  5. Kontynuuj dodawanie pól, aż będziesz mieć wszystkie, których potrzebujesz. Jeśli próbujesz przygotować skoroszyt zawierający funkcje danych korzystające z wielu tabel, zmień źródło danych funkcji danych na nową tabelę.

Problem

Co się nie udało

Zwrócona nieprawidłowa wartość

Jeśli argument przeszukiwany_zakres ma wartość PRAWDA lub został pominięty, pierwsza kolumna musi być posortowana alfabetycznie lub liczbowo. Jeśli pierwsza kolumna nie jest posortowana, zwracana może być nieoczekiwana wartość. Posortuj pierwszą kolumnę lub użyj wartości FAŁSZ, aby uzyskać dokładne dopasowanie.

Wartość #N/D w komórce

  • Jeśli argument przeszukiwany_zakres ma wartość PRAWDA, a wartość argumentu szukana_wartość jest mniejsza od najmniejszej wartości w pierwszej kolumnie tabeli tabela_tablica, wówczas zwracana jest wartość błędu #N/D.

  • Jeśli argument przeszukiwany_zakres ma wartość FAŁSZ, wartość błędu #N/D oznacza, że nie znaleziono dokładnej liczby.

Aby uzyskać więcej informacji dotyczących usuwania błędów #N/D w funkcji WYSZUKAJ.PIONOWO, zobacz Naprawianie błędu #N/D! w funkcji WYSZUKAJ.PIONOWO.

Wartość #ADR! w komórce

Jeśli wartość nr_kolumny jest większa niż liczba kolumn określona za pomocą wartości tabela_tablica, zostanie zwrócona wartość #ADR!. wartość błędu #ADR!.

Aby uzyskać więcej informacji dotyczących usuwania błędów #ADR! w funkcji WYSZUKAJ.PIONOWO, zobacz Jak poprawić błąd #ADR!.

Wartość #ARG! w komórce

Jeśli wartość tabela_tablica jest mniejsza niż 1, zostanie zwrócona wartość #ARG!. wartość błędu #ADR!.

Aby uzyskać więcej informacji dotyczących usuwania błędów #ARG! w funkcji WYSZUKAJ.PIONOWO, zobacz Naprawianie błędu #ARG! w funkcji WYSZUKAJ.PIONOWO.

Wartość #NAZWA? w komórce

Wartość błędu #NAZWA? zazwyczaj oznacza, że w formule brakuje cudzysłowu. Aby wyszukać nazwisko osoby, upewnij się, że w formule zostało ono ujęte w cudzysłów. Na przykład wprowadź nazwisko "Pawłowski" w formule =WYSZUKAJ.PIONOWO("Pawłowski";B2:E7;2;FAŁSZ).

Aby uzyskać więcej informacji, zobacz Jak naprawić błąd #NAZWA.

#ROZLANIE! w komórce

Ten konkretny błąd #ROZLANIE! zwykle oznacza, że formuła polega na przecięciu pośrednim dla wartości odnośnika i używa całej kolumny jako odwołania. Na przykład =WYSZUKAJ.PIONOWO(A:A,A:C,2,FAŁSZ). Aby rozwiązać ten problem, zakotwicz odwołanie odnośnika za pomocą operatora @ w następujący sposób: =WYSZUKAJ.PIONOWO(@A:A,A:C,2,FAŁSZ). Alternatywnie można użyć tradycyjnej metody funkcji WYSZUKAJ.PIONOWO i odwołać się do pojedynczej komórki zamiast całej kolumny: =WYSZUKAJ.PIONOWO(A2,A:C,2,FAŁSZ).

Czynność

Uzasadnienie

Używaj odwołań bezwzględnych dla argumentu przeszukiwany_zakres.

Dzięki odwołaniom bezwzględnym można wypełniać formułę tak, aby zawsze przeszukiwała ten sam zakres.

Dowiedz się, jak korzystać z bezwzględnych odwołań do komórek.

Nie przechowuj wartości liczbowych ani dat jako tekstu.

W przypadku wyszukiwania wartości liczbowych lub dat upewnij się, że dane w pierwszej kolumnie zdefiniowanej za pomocą argumentu tabela_tablica nie są przechowywane jako wartości tekstowe. W przeciwnym razie funkcja WYSZUKAJ.PIONOWO może zwrócić niepoprawną lub nieoczekiwaną wartość.

Posortuj pierwszą kolumnę.

Posortuj pierwszą kolumnę tabeli tabela_tablica przed użyciem funkcji WYSZUKAJ.PIONOWO, jeśli argument przeszukiwany_zakres ma wartość PRAWDA.

Używaj symboli wieloznacznych.

Jeśli argument przeszukiwany_zakres ma wartość FAŁSZ, a szukana_wartość jest tekstem, przy określaniu argumentu szukana_wartość można używać symboli wieloznacznych: znaku zapytania (?) i gwiazdki (*). Znak zapytania odpowiada dowolnemu pojedynczemu znakowi. Gwiazdka odpowiada dowolnej sekwencji znaków. Jeśli chcesz znaleźć rzeczywisty znak zapytania lub gwiazdkę, wpisz tyldę (~) przed znakiem.

Na przykład formuła =WYSZUKAJ.PIONOWO("Pawłowsk?";B2:E7;2;FAŁSZ) spowoduje wyszukanie wszystkich wystąpień tekstu Pawłowski, przy czym ostatnia litera może być różna.

Upewnij się, że dane nie zawierają błędnych znaków.

W przypadku wyszukiwania w pierwszej kolumnie wartości tekstowych upewnij się, że dane w tej kolumnie nie zawierają początkowych ani końcowych spacji, niespójnych cudzysłowów prostych (' lub ") ani drukarskich (‘ lub „”), znaków zapytania ani znaków niedrukowanych. Wystąpienie takich znaków może spowodować zwrócenie przez funkcję WYSZUKAJ.PIONOWO nieoczekiwanej wartości.

Spróbuj użyć funkcji OCZYŚĆ lub funkcji USUŃ.ZBĘDNE.ODSTĘPY, aby usunąć końcowe spacje za wartościami tabeli w komórce.

Potrzebujesz dodatkowej pomocy?

Zawsze możesz zadać pytanie ekspertowi w społeczności technicznej programu Excel lub uzyskać pomoc techniczną w Społecznościach.

Zobacz też

Funkcja XLOOKUP

Klip wideo: kiedy i jak używać funkcji WYSZUKAJ.PIONOWO

Podręczna karta informacyjna: podsumowanie wiadomości o funkcji WYSZUKAJ.PIONOWO

Jak naprawić błąd #N/D! w funkcji WYSZUKAJ.PIONOWO

Wyszukiwanie wartości przy użyciu funkcji WYSZUKAJ.PIONOWO, INDEKS i PODAJ.POZYCJĘ

WYSZUKAJ.POZIOMO, funkcja

Potrzebujesz dalszej pomocy?

Chcesz uzyskać więcej opcji?

Poznaj korzyści z subskrypcji, przeglądaj kursy szkoleniowe, dowiedz się, jak zabezpieczyć urządzenie i nie tylko.

Społeczności pomagają zadawać i odpowiadać na pytania, przekazywać opinie i słuchać ekspertów z bogatą wiedzą.

Czy te informacje były pomocne?

Jaka jest jakość języka?
Co wpłynęło na Twoje wrażenia?
Jeśli naciśniesz pozycję „Wyślij”, Twoja opinia zostanie użyta do ulepszania produktów i usług firmy Microsoft. Twój administrator IT będzie mógł gromadzić te dane. Oświadczenie o ochronie prywatności.

Dziękujemy za opinię!

×