관련 주제
×
수식 및 함수
Microsoft로 로그인
로그인하거나 계정을 만듭니다.
안녕하세요.
다른 계정을 선택합니다.
계정이 여러 개 있음
로그인할 계정을 선택합니다.
수식 및 함수

COUNTIF 함수

통계 함수 중 하나인 COUNTIF를 사용하여 기준을 충족하는 셀의 개수를 계산할 수 있습니다(예: 고객 목록에 특정 도시가 표시되는 횟수 계산).

가장 간단한 형식의 COUNTIF는 다음과 같은 의미입니다.

  • =COUNTIF(찾으려는 위치, 찾으려는 항목)

예:

  • =COUNTIF(A2:A5,"런던")

  • =COUNTIF(A2:A5,A4)

브라우저가 비디오를 지원하지 않습니다. Microsoft Silverlight, Adobe Flash Player 또는 Internet Explorer 9를 설치하세요.

COUNTIF(range, criteria)

인수 이름

설명

range   (필수 요소)

개수를 구하려는 셀의 그룹입니다. Range에는 숫자, 배열, 이름이 지정된 범위 또는 숫자를 포함하는 참조 영역이 포함될 수 있습니다. 빈 셀과 텍스트 값은 무시됩니다.

워크시트에서 범위를 선택하는 방법을 알아보세요.

criteria   (필수 요소)

어떤 셀의 개수를 셀지 결정하는 숫자, 식, 셀 참조 또는 텍스트 문자열입니다

예를 들어 32와 같은 숫자, ">32"와 같은 비교, B4와 같은 셀 또는 "사과"와 같은 단어를 사용할 수 있습니다.

COUNTIF는 하나의 조건만 사용합니다. 여러 개의 조건을 사용하려는 경우 COUNTIFS를 사용합니다.

예제

Excel에서 이러한 예제를 사용하려면 다음 표의 데이터를 복사하여 새 워크시트의 A1 셀에 붙여 넣습니다.

데이터

데이터

사과

32

오렌지

54

복숭아

75

사과

86

수식

설명

=COUNTIF(A2:A5,"사과")

셀 A2에서 A5까지의 범위에서 사과가 포함된 셀의 개수를 계산합니다. 결과는 2입니다.

=COUNTIF(A2:A5,A4)

셀 A2에서 A5까지의 범위에서 복숭아(A4의 값)가 포함된 셀의 개수를 계산합니다. 결과는 1입니다.

=COUNTIF(A2:A5,A2)+COUNTIF(A2:A5,A3)

셀 A2에서 A5까지 사과(A2의 값) 및 오렌지(A3의 값) 개수를 계산합니다. 결과는 3입니다. 이 수식에서는 COUNTIF를 두 번 사용하여 식당 조건 하나씩 여러 조건을 지정합니다. COUNTIFS 함수를 사용할 수도 있습니다.

=COUNTIF(B2:B5,">55")

셀 B2에서 B5까지의 범위에서 값이 55보다 큰 셀의 개수를 계산합니다. 결과는 2입니다.

=COUNTIF(B2:B5,"<>"&B4)

셀 B2에서 B5까지의 범위에서 값이 75가 아닌 셀의 개수를 계산합니다. 앰퍼샌드(&)는 같지 않음(<>)의 비교 연산자와 B4의 값을 병합하여 =COUNTIF(B2:B5,"<>75")를 읽습니다. 결과는 3입니다.

=COUNTIF(B2:B5,">=32")-COUNTIF(B2:B5,"<=85")

셀 B2에서 B5까지의 범위에서 값이 32보다 크거나(>) 같고(=) 85보다 작거나(<) 같은(=) 셀의 개수를 계산합니다. 결과는 1입니다.

=COUNTIF(A2:A5,"*")

셀 A2에서 A5까지의 범위에서 텍스트가 포함된 셀의 개수를 계산합니다. 별표(*)가 임의의 문자와 일치시키는 와일드카드 문자로 사용됩니다. 결과는 4입니다.

=COUNTIF(A2:A5,"??자")

셀 A2에서 A5까지의 범위에서 "자"로 끝나고 글자 수가 정확히 7개인 셀의 개수를 계산합니다. 물음표(?)가 개별 문자와 일치시키는 와일드카드 문자로 사용됩니다. 결과는 2입니다.

일반적인 문제

문제

원인

긴 문자열에 대해 잘못된 값이 반환됩니다.

COUNTIF 함수를 사용하여 255자를 초과하는 문자열을 일치시킬 경우 잘못된 결과가 반환됩니다.

255자를 초과하는 문자열과 일치시키려면 CONCATENATE 함수 또는 결합 연산자 &를 사용합니다. 예를 들어 =COUNTIF(A2:A5,"긴 문자열"&"다른 긴 문자열")을 사용할 수 있습니다.

값을 예상했지만 아무런 값이 반환되지 않습니다.

조건 인수를 따옴표 안에 넣어야 합니다.

COUNTIF 수식에서 다른 워크시트를 참조할 때 #VALUE! 오류가 표시됩니다.

이 오류는 함수가 포함된 수식이 닫힌 워크시트의 셀 또는 범위를 참조하고 셀을 계산하는 경우 발생합니다. 이 기능이 작동하려면 다른 통합 문서가 열려 있어야 합니다.

모범 사례

실행

이유

COUNTIF는 텍스트 문자열에서 대소문자를 무시합니다.

조건 은 대/소문자를 구분하지 않습니다. 다시 말해 "apples"라는 문자열과 "APPLES"라는 문자열은 서로 일치하는 셀로 취급됩니다.

와일드카드 문자를 사용합니다.

와일드 카드(물음표(?)와 별표(*))를 기준에서 사용할 수 있습니다. 물음표는 한 문자에 해당합니다. 별표는 개수에 상관없는 임의의 문자열에 해당합니다. 실제 물음표나 별표를 찾으려면 해당 문자 앞에 물결표(~)를 입력합니다.

예를 들어, =COUNTIF(A2:A5,"apple?")는 마지막 문자가 변할 수 있는 “apple”의 모든 인스턴스 개수를 계산합니다.

데이터에 잘못된 문자가 없는지 확인합니다.

텍스트 값을 계산할 때는 데이터에 앞/뒤 공백을 두거나, 곧은 따옴표와 둥근 따옴표를 일관성 없이 사용하거나, 인쇄할 수 없는 문자를 사용하지 않도록 주의하세요. 그럴 경우 COUNTIF에서 예기치 않은 값이 반환될 수 있습니다.

CLEAN 함수 또는 TRIM 함수를 사용해 보세요.

편의를 위해 이름이 지정된 범위를 사용합니다.

COUNTIF는 수식에서 명명된 범위(예: =COUNTIF(fruit,">=32")-COUNTIF(fruit,">85")를 지원합니다. 이름이 지정된 범위는 현재 워크시트, 동일한 통합 문서의 다른 워크시트 또는 다른 통합 문서에 있을 수 있습니다. 다른 통합 문서에서 참조하려면 해당하는 두 번째 통합 문서도 열려 있어야 합니다.

참고: COUNTIF 함수는 셀 배경 색이나 글꼴 색을 바탕으로 셀 개수를 세지 않습니다. 단, Excel에서는 배경 색 또는 글꼴 색을 바탕으로 셀에 대해 Microsoft VBA(Visual Basic for Applications) 연산을 사용하는 UDF(사용자 정의 함수)를 지원합니다. 다음은 VBA를 사용하여 특정 셀 색을 갖는 셀 개수를 세는 방법에 관한 예제입니다.

추가 지원

언제든지 Excel 기술 커뮤니티에서 전문가에게 문의하거나 커뮤니티에서 지원을 받을 수 있습니다.

참고 항목

COUNTIFS 함수

IF 함수

COUNTA 함수

Excel의 수식 개요

IFS 함수

SUMIF 함수

도움이 더 필요하세요?

더 많은 옵션을 원하세요?

구독 혜택을 살펴보고, 교육 과정을 찾아보고, 디바이스를 보호하는 방법 등을 알아봅니다.

커뮤니티를 통해 질문하고 답변하고, 피드백을 제공하고, 풍부한 지식을 갖춘 전문가의 의견을 들을 수 있습니다.

이 정보가 유용한가요?

언어 품질에 얼마나 만족하시나요?
사용 경험에 어떠한 영향을 주었나요?
제출을 누르면 피드백이 Microsoft 제품과 서비스를 개선하는 데 사용됩니다. IT 관리자는 이 데이터를 수집할 수 있습니다. 개인정보처리방침

의견 주셔서 감사합니다!

×